; ****************************************************
; Ridici program pro Atmel simulatoru EPROM, verze 2.0
; ****************************************************

MODE	equ 0B1h	; 0 = Simulace, 1 = Download
HCDAT	equ 0B2h	; data pro HC4094
HCCLK	equ 0B3h	; clock pro HC4094
RST2	equ 0B4h	; 1 = /RESET
RST1	equ 0B5h	; 0 = RESET (pri cteni tlacitko ERASE)
WRITE	equ 0B7h	; 0 = write to RAM

	org 0

; *********************
; Inicializace registru
; *********************

Start:	mov TMOD,#20h	; T1 mode 2 (autoreload TL<<TH)
	mov TH1,#0FFh	; 57600Bd (SMOD nutno nastavit na 1)
	mov PCON,#80h	; double Bd/access SM0 @ SCON
	mov SCON,#70h	; 8bit, enable Rx
	mov PCON,#0C0h	; double Bd/access FE @ SCON
	setb TR1	; pustit T1

Restrt:	mov SP,#10h	; definovat ukazatel zasobniku
	mov P1,#0FFh	; odpojit CPU od datove sbernice
	clr RI		; vycistit prijimaci bufer UARTu
	clr MODE	; nastavit MODE emulace
	setb RST1	; deaktivace RESET
	clr RST2	; deaktivace /RESET
	clr SCON.7	; vynulovat pripadny STOPBIT error

; ***************************
; Zde beha program nejcasteji
; ***************************

Emuluj:	jb RI,Prijem	; byl prijat znak via UART
	jb RST1,Emuluj	; stisk tlacitka ERASE

; *************************************************
; vyplneni emulacni pameti od stisku tlacitka ERASE
; *************************************************

Erase:	clr RST1	; aktivovat RESET
	setb RST2	; aktivovat /RESET
	setb MODE	; MODE prepnout na download

	mov R0,#17	; 16bitu + inicializace HCCLK
	mov R1,#0	; R1:R0 - stinovy LFSR registr
	clr HCDAT	; nasouvat same nuly
erase0:	setb HCCLK	; 1x posun registru 74HC4094
	clr HCCLK
	djnz R0,erase0	; dalsi bit 74HC4094
	clr WRITE
	setb WRITE	; zapsat 0xFF na adresu 0000h

	mov A,#80h	; falesny stav pro vyvedeni LFSR
			; z nuloveho stavu
eralop:	anl A,#0B4h	; polynom 16bitoveho LFSR
	mov C,PSW.0	; vysledek polynomu
	mov HCDAT,C	; nasunout do kaskady 74HC4094
	setb HCCLK	; (..potvrdit CLOCKem)
	clr HCCLK
	mov A,R0	; a do spojenych registru R1:R0,
	rlc A		; ktere tvori online obraz stavu
	mov R0,A	; v kaskade 74HC4094
	mov A,R1
	rlc A
	mov R1,A
	clr WRITE	; na vygenerovanou adresu zapsat
	setb WRITE	; stav 0xFF

	cjne R1,#80h,eralop ; takto adresovat vsech 65535
	cjne R0,#0,eralop   ; adres mimo adresu 0000h

	jmp Restrt	; a navrat do hlavni smycky

; *******************************
; Download dat z PC do simulatoru
; *******************************

Prijem:	setb WRITE	; deaktivovat zapis do RAM
	clr RST1	; aktivovat RESET
	setb RST2	; aktivovat /RESET
	setb MODE	; MODE nastavit na prenos dat

PrijeL:	call GetChr	; nacist prvni znak
	jc Restrt	; pri vyprseni casu konec prenosu
	cjne A,#0Ah,IGLF
	jmp PrijeL	; ignorovat LF
IGLF:	cjne A,#0Dh,IGCR
	jmp PrijeL	; ignorovat CR
IGCR:	cjne A,#3Ah,Errors ; veta zacina dvojteckou

	mov R0,#0	; vynulovat CRC

	call GetByt	; nacist 1. byte - delku vety
	jc Errors	; pokud neprisel, je to chyba
	mov R1,A
	
	call GetAdr	; nacist 2. a 3. byte - adresu
	jc Errors	; pokud neprisla, je to chyba

	call GetByt	; nacist 4. byte - typ vety
	jc Errors	; pokud neprisel, je to chyba
	cjne A,#2,PrijeT
PrijeT:	jnc Errort	; povoleny jen typy 0 a 1

PrijeS:	cjne R1,#0,PrijeN

	call GetByt	; nacist kontrolni soucet
	jc Errors	; pokud neprisel, je to chyba

	mov A,R0	; pri chybe CRC
	jnz Errors	; vyvolat chybu

	jmp PrijeL	; cekat na dalsi vetu

PrijeN:	call GetByt	; nacist byte obsahu
	jc Errors	; pokud neprisel, je to chyba
	mov P1,A	; datovy byte hodit na sbernici
	call SndAdr	; adresu hodit na 74HC4094
	clr WRITE	; a zapsat do RAM
	setb WRITE
	inc DPTR	; zvednout adresu +1
	dec R1
	jmp PrijeS
	
; *************
; Chyba syntaxe
; *************

Errors:	mov A,#11111110b ; kod blikani LED
	jmp Error

; ***********************
; Nepovoleny TAG IntelHex
; ***********************

Errort:	mov A,#11101010b ; kod blikani LED

; *************************************
; Vyblikavani chyboveho kodu
; (mozno zrusit stiskem tlacitka Erase)
; *************************************

Error:	setb C		; prodlouzeni kodu o jeden bit
	setb RST2	; aktivovat /RESET
	mov P1,#0FFh	; odpojit CPU od datove sbernice
Errorl:	rlc A		; dalsi stav blikaciho kodu
	mov MODE,C	; poslat na LEDku
	setb RST1	; umoznit test tlacitka ERASE
	jb RST1,Errorn	; pri jeho stisku
	jmp Erase	; vymazat RAM
Errorn:	clr RST1	; opet aktivovat RESET
Errorw:	djnz R3,Errorw	; blikat v intervalu
	djnz R4,Errorw	; 9 x 0,14sec = 1,285 sec
	jmp Errorl

; *******************
; prijem byte z UARTu
; *******************

GetByt:	call GetChr	; prijmout prvni znak
	jnc GetBy1	; pokud prisel, jdeme dal,
	ret		; jinak vyprsel cas a nic..
GetBy1:	call AscBin	; pokus o prevod na nibble
	rl A
	rl A
	rl A
	rl A
	mov B,A		; B = prvni (horni) nibble
	call GetChr	; prijmout druhy znak
	jnc GetBy2	; pokud prisel, jdeme dal,
	ret		; jinak vyprsel cas a nic..
GetBy2:	call AscBin	; pokus o prevod na nibble
	orl A,B		; pripojit horni nibble
	mov B,A		; a uschovat vysledek
	add A,R0	; aktualizovat CRC
	mov R0,A
	mov A,B		; obnovit nacteny byte
	clr C		; priznak platnych dat
	ret

; *********************
; prijem adresy z UARTu
; *********************

GetAdr:	call GetByt	; nacist prvni bajt
	jnc GetAd1	; pokud prisel, jdeme dal,
	ret		; jinak konec
GetAd1:	mov DPH,A	; vyssi bajt ulozit do DPH
	call GetByt	; pokus o nacteni druheho bajtu
	mov DPL,A	; a jeho ulozeni do DPL
	ret

; *******************
; Prevod ASCII na BIN
; *******************

AscBin:	clr C
	subb A,#48	; vsechny znaky "pod" nulou
	jc Errors	; vyvolaji chybu
	subb A,#10	; znaky 0..9
	jc AscBi4	; se prevedou
	subb A,#7	; znaky :;<=>?@
	jc Errors	; vyvolaji chybu
	cjne A,#6,AscBi2 ; znaky A..F
AscBi2:	jc AscBi4	; se prevedou
	subb A,#32
	jc Errors	; preskocit dalsi znaky
	cjne A,#6,AscBi3 ; a mimo a..f
AscBi3:	jnc Errors	; vyvolat chybu
AscBi4:	add A,#10	; ostatni znaky se prevedou
	ret

; ********************
; prijem znaku z UARTu
; ********************

GetChr:	mov R5,#10	; 10 x 0,1s = 1s timeout
GetCh1:	mov R6,#100	; 100 x 1ms = 0,1s
GetCh2:	mov R7,#230	; casovani 1ms
GetCh3:	jb RI,GetChc	; ..neco prislo z UARTu..
	djnz R7,GetCh3
	djnz R6,GetCh2
	djnz R5,GetCh1	; ..cas vyprsel..
	setb C		; nastavit priznak neplatnych dat
	ret		; a navrat

GetChc:	jb SCON.7,Errorf ; testovat STOPBIT error
	mov A,SBUF	; jinak nacist prijaty znak
	clr RI		; shodit priznak prijateho znaku
	clr C		; nastavit priznak platnych dat
	ret		; a konec

; *****************************
; Chyba prenosoveho ramce UARTu
; *****************************

Errorf:	mov A,#11111010b ; kod blikani LED
	jmp Error

; ***********************************
; nasune adresu do posuvnych registru
; ***********************************

SndAdr:	mov A,DPH	; vyssi cast adresy

	mov C,ACC.2	; A(10)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov C,ACC.1	; A(9)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov C,ACC.3	; A(11)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov C,ACC.5	; A(13)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov C,ACC.7	; A(15)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov C,ACC.4	; A(12)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov C,ACC.6	; A(14)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov C,ACC.0	; A(8)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov A,DPL	; nizsi cast adresy

	mov C,ACC.7	; A(7)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov C,ACC.6	; A(6)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov C,ACC.5	; A(5)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov C,ACC.4	; A(4)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov C,ACC.3	; A(3)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov C,ACC.2	; A(2)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov C,ACC.1	; A(1)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	mov C,ACC.0	; A(0)
	mov HCDAT,C
	setb HCCLK
	clr HCCLK

	ret

	end